c
c
c     ###################################################
c     ##  COPYRIGHT (C)  1990  by  Jay William Ponder  ##
c     ###################################################
c
c     #############################################################
c     ##                                                         ##
c     ##  function random  --  portable random number generator  ##
c     ##                                                         ##
c     #############################################################
c
c
c     "random" generates a random number on [0,1] via a long
c     period generator due to L'Ecuyer with Bays-Durham shuffle
c
c     literature references :
c
c     P. L'Ecuyer, Communications of the ACM, 31, 742-774 (1988)
c
c     W. H. Press, S. A. Teukolsky, W. T. Vetterling and B. P.
c     Flannery, Numerical Recipes (Fortran), 2nd Ed., Cambridge
c     University Press, 1992, section 7-1
c
c
      function random ()
      implicit none
      include 'files.i'
      include 'inform.i'
      include 'iounit.i'
      integer im1,ia1,iq1,ir1
      integer im2,ia2,iq2,ir2
      integer big,ntable
      integer imm1,ndiv
      real*8 factor
      parameter (im1=2147483563)
      parameter (ia1=40014)
      parameter (iq1=53668)
      parameter (ir1=12211)
      parameter (im2=2147483399)
      parameter (ia2=40692)
      parameter (iq2=52774)
      parameter (ir2=3791)
      parameter (big=141803398)
      parameter (ntable=32)
      parameter (imm1=im1-1)
      parameter (ndiv=1+imm1/ntable)
      parameter (factor=1.0d0/im1)
      integer j,k,seed,seed2
      integer iy,itable(ntable)
      integer ikey,next,freeunit
      integer year,month,day
      integer hour,minute,second
      real*8 random
      character*20 keyword
      character*60 keyfile
      character*80 record,string
      logical initial,exist
      save initial,seed,seed2,iy,itable
      data initial  / .true. /
c
c
c     random number seed is first set to a big number,
c     then incremented by the seconds elapsed this decade
c
      if (initial) then
         initial = .false.
         seed = big
         call calendar (year,month,day,hour,minute,second)
         year = mod(year,10)
         seed = seed + 32140800*year + 2678400*(month-1)
         seed = seed + 86400*(day-1) + 3600*hour
         seed = seed + 60*minute + second
c
c     check for the existence of a keyword file
c
         keyfile = filename(1:leng)//'.key'
         call version (keyfile,'old')
         inquire (file=keyfile,exist=exist)
c
c     search the keyword file for a random number seed
c
         if (exist) then
            ikey = freeunit ()
            open (unit=ikey,file=keyfile,status='old')
            rewind (unit=ikey)
            dowhile (.true.)
               read (ikey,10,end=20)  record
   10          format (a80)
               next = 1
               call gettext (record,keyword,next)
               call upcase (keyword)
               if (keyword(1:11) .eq. 'RANDOMSEED ') then
                  string = record(next:80)
                  read (string,*,err=20)  seed
                  seed = max(1,seed)
               end if
            end do
   20       continue
            close (unit=ikey)
         end if
c
c     print the value used for the random number seed
c
         if (verbose) then
            write (iout,30)  seed
   30       format (/,' RANDOM  --  Initialized with SEED of',i12)
         end if
c
c     warm up and then load the shuffling table
c
         seed2 = seed
         do j = ntable+8, 1, -1
            k = seed / iq1
            seed = ia1 * (seed-k*iq1) - k*ir1
            if (seed .lt. 0)  seed = seed + im1
            if (j .le. ntable)  itable(j) = seed
         end do
         iy = itable(1)
      end if
c
c     get a new random number value each call
c
      k = seed / iq1
      seed = ia1*(seed-k*iq1) - k*ir1
      if (seed .lt. 0)  seed = seed + im1
      k = seed2 / iq2
      seed2 = ia2*(seed2-k*iq2) - k*ir2
      if (seed2 .lt. 0)  seed2 = seed2 + im2
      j = 1 + iy/ndiv
      iy = itable(j) - seed2
      itable(j) = seed
      if (iy .lt. 1)  iy = iy + imm1
      random = factor * iy
c
c     print the value of the current random number
c
      if (debug) then
c        write (iout,40)  random
c  40    format (' RANDOM  --  The Random Number Value is',f12.8)
      end if
      return
      end
